mirror of
https://github.com/input-leap/input-leap.git
synced 2026-09-30 13:15:39 +02:00
Povilas Kanapickas
7fda0c91c7
The final build products are produced by CMake install action. However, the installer was configured topick files from intermediate output location. As a result not all required libraries were being picked up.
91 lines
3.9 KiB
Plaintext
91 lines
3.9 KiB
Plaintext
#define MyAppName "InputLeap"
|
|
#define MyAppVersion "@INPUTLEAP_VERSION_MAJOR@.@INPUTLEAP_VERSION_MINOR@.@INPUTLEAP_VERSION_PATCH@.@INPUTLEAP_BUILD_NUMBER@"
|
|
#define MyAppTextVersion "@INPUTLEAP_VERSION@"
|
|
#define MyAppPublisher "InputLeap contributors"
|
|
#define MyAppURL "https://github.com/input-leap/input-leap/wiki"
|
|
#define MyAppCopyright "Copyright (C) InputLeap contributors"
|
|
#define MyAppExeName "input-leap.exe"
|
|
#define MyAppServiceName "InputLeap"
|
|
#define MyAppServiceExe "input-leapd.exe"
|
|
#define MyAppServiceDesc "Manages the InputLeap background processes."
|
|
#define MyAppListenerDesc "InputLeap Listener"
|
|
|
|
[Setup]
|
|
AppId={{41036EA6-3F7A-4803-8AE0-46912391EFCC}
|
|
AppName={#MyAppName}
|
|
AppVersion={#MyAppTextVersion}
|
|
AppVerName={#MyAppName} {#MyAppTextVersion}
|
|
AppPublisher={#MyAppPublisher}
|
|
AppPublisherURL={#MyAppURL}
|
|
AppSupportURL={#MyAppURL}
|
|
AppUpdatesURL={#MyAppURL}
|
|
DefaultDirName={pf}\{#MyAppName}
|
|
DisableProgramGroupPage=yes
|
|
LicenseFile=@CMAKE_CURRENT_SOURCE_DIR@/res/License.rtf
|
|
OutputDir=@CMAKE_INSTALL_PREFIX@/../installer-inno/bin
|
|
OutputBaseFilename=InputLeapSetup-{#MyAppTextVersion}
|
|
SetupIconFile=@CMAKE_CURRENT_SOURCE_DIR@/res/input-leap.ico
|
|
VersionInfoProductTextVersion={#MyAppTextVersion}
|
|
VersionInfoProductVersion={#MyAppVersion}
|
|
VersionInfoTextVersion={#MyAppTextVersion}
|
|
VersionInfoVersion={#MyAppVersion}
|
|
VersionInfoCopyright={#MyAppCopyright}
|
|
|
|
Compression=lzma
|
|
SolidCompression=yes
|
|
ArchitecturesInstallIn64BitMode=x64
|
|
UninstallDisplayIcon={app}\{#MyAppExeName}
|
|
|
|
#include "scripts\lang\english.iss"
|
|
|
|
[Tasks]
|
|
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked
|
|
|
|
[Files]
|
|
Source: "@CMAKE_INSTALL_PREFIX@/*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs
|
|
; NOTE: Don't use "Flags: ignoreversion" on any shared system files
|
|
|
|
[Icons]
|
|
Name: "{commonprograms}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"
|
|
Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon
|
|
|
|
[Run]
|
|
; there's no "check if exists" or "insert if not exists" for netsh's firewall commands
|
|
; to avoid duplicate entries remove the existing rule (fails if it doesn't exist) before adding
|
|
Filename: {sys}\netsh.exe; Parameters: "advfirewall firewall delete rule name=""{#MyAppListenerDesc}"""; Flags: runhidden
|
|
Filename: {sys}\netsh.exe; Parameters: "advfirewall firewall add rule name=""{#MyAppListenerDesc}"" protocol=TCP dir=in localport=24800 action=allow"; Flags: runhidden
|
|
Filename: {sys}\sc.exe; Parameters: "create {#MyAppServiceName} start= auto binPath= ""\""{app}\{#MyAppServiceExe}\"""""; Flags: runhidden
|
|
Filename: {sys}\sc.exe; Parameters: "description {#MyAppServiceName} ""{#MyAppServiceDesc}"""; Flags: runhidden
|
|
Filename: {sys}\sc.exe; Parameters: "start {#MyAppServiceName}"; Flags: runhidden
|
|
Filename: "{app}\{#MyAppExeName}"; Description: "{cm:LaunchProgram,{#StringChange(MyAppName, '&', '&&')}}"; Flags: nowait postinstall skipifsilent
|
|
|
|
[UninstallDelete]
|
|
Type: filesandordirs; Name: "{commonappdata}\InputLeap"
|
|
|
|
[UninstallRun]
|
|
Filename: {sys}\taskkill; Parameters: "/im {#MyAppExeName} /f /t"; Flags: runhidden
|
|
Filename: {sys}\net.exe; Parameters: "stop {#MyAppServiceName}"; Flags: runhidden
|
|
Filename: {sys}\sc.exe; Parameters: "delete {#MyAppServiceName}"; Flags: runhidden
|
|
Filename: {sys}\netsh.exe; Parameters: "advfirewall firewall delete rule name=""{#MyAppListenerDesc}"""; Flags: runhidden
|
|
|
|
[CustomMessages]
|
|
DependenciesDir="redist"
|
|
|
|
; shared code for installing the products
|
|
#include "scripts\products.iss"
|
|
#include "scripts\products\stringversion.iss"
|
|
#include "scripts\products\winversion.iss"
|
|
#include "scripts\products\msiproduct.iss"
|
|
#include "scripts\products\vcredist2017.iss"
|
|
|
|
[Code]
|
|
function InitializeSetup(): boolean;
|
|
begin
|
|
// initialize windows version
|
|
initwinversion();
|
|
|
|
vcredist2017('14'); // min allowed version is 14.0
|
|
|
|
Result := true;
|
|
end;
|