mirror of
https://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git
synced 2026-04-03 12:05:13 +02:00
c73049389e
When running in a non-root time namespace, the global VDSO data page is replaced by a dedicated namespace data page and the global data page is mapped next to it. Detailed explanations can be found at commit660fd04f93("lib/vdso: Prepare for time namespace support"). When it happens, __kernel_get_syscall_map and __kernel_get_tbfreq and __kernel_sync_dicache don't work anymore because they read 0 instead of the data they need. To address that, clock_mode has to be read. When it is set to VDSO_CLOCKMODE_TIMENS, it means it is a dedicated namespace data page and the global data is located on the following page. Add a macro called get_realdatapage which reads clock_mode and add PAGE_SIZE to the pointer provided by get_datapage macro when clock_mode is equal to VDSO_CLOCKMODE_TIMENS. Use this new macro instead of get_datapage macro except for time functions as they handle it internally. Fixes:74205b3fc2("powerpc/vdso: Add support for time namespaces") Reported-by: Jason A. Donenfeld <Jason@zx2c4.com> Closes: https://lore.kernel.org/all/ZtnYqZI-nrsNslwy@zx2c4.com/ Signed-off-by: Christophe Leroy <christophe.leroy@csgroup.eu> Acked-by: Michael Ellerman <mpe@ellerman.id.au> Signed-off-by: Jason A. Donenfeld <Jason@zx2c4.com>
65 lines
1.5 KiB
ArmAsm
65 lines
1.5 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-or-later */
|
|
/*
|
|
* Access to the shared data page by the vDSO & syscall map
|
|
*
|
|
* Copyright (C) 2004 Benjamin Herrenschmuidt (benh@kernel.crashing.org), IBM Corp.
|
|
*/
|
|
|
|
#include <asm/processor.h>
|
|
#include <asm/ppc_asm.h>
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/unistd.h>
|
|
#include <asm/vdso.h>
|
|
#include <asm/vdso_datapage.h>
|
|
|
|
.text
|
|
|
|
/*
|
|
* void *__kernel_get_syscall_map(unsigned int *syscall_count) ;
|
|
*
|
|
* returns a pointer to the syscall map. the map is agnostic to the
|
|
* size of "long", unlike kernel bitops, it stores bits from top to
|
|
* bottom so that memory actually contains a linear bitmap
|
|
* check for syscall N by testing bit (0x80000000 >> (N & 0x1f)) of
|
|
* 32 bits int at N >> 5.
|
|
*/
|
|
V_FUNCTION_BEGIN(__kernel_get_syscall_map)
|
|
.cfi_startproc
|
|
mflr r12
|
|
.cfi_register lr,r12
|
|
mr. r4,r3
|
|
get_realdatapage r3, r11
|
|
mtlr r12
|
|
#ifdef __powerpc64__
|
|
addi r3,r3,CFG_SYSCALL_MAP64
|
|
#else
|
|
addi r3,r3,CFG_SYSCALL_MAP32
|
|
#endif
|
|
crclr cr0*4+so
|
|
beqlr
|
|
li r0,NR_syscalls
|
|
stw r0,0(r4)
|
|
blr
|
|
.cfi_endproc
|
|
V_FUNCTION_END(__kernel_get_syscall_map)
|
|
|
|
/*
|
|
* void unsigned long long __kernel_get_tbfreq(void);
|
|
*
|
|
* returns the timebase frequency in HZ
|
|
*/
|
|
V_FUNCTION_BEGIN(__kernel_get_tbfreq)
|
|
.cfi_startproc
|
|
mflr r12
|
|
.cfi_register lr,r12
|
|
get_realdatapage r3, r11
|
|
#ifndef __powerpc64__
|
|
lwz r4,(CFG_TB_TICKS_PER_SEC + 4)(r3)
|
|
#endif
|
|
PPC_LL r3,CFG_TB_TICKS_PER_SEC(r3)
|
|
mtlr r12
|
|
crclr cr0*4+so
|
|
blr
|
|
.cfi_endproc
|
|
V_FUNCTION_END(__kernel_get_tbfreq)
|