mirror of
https://github.com/macvim-dev/macvim.git
synced 2026-02-05 11:33:15 +01:00
5e0c33363e
Additional test fixes:
- test_macvim:
- remove check.vim import which is now done automatically
- test_gui:
- Test_Buffers_Menu add conditional check to not run the
LoadBufferMenu autocmd since in MacVim we don't use it.
- Test_scrollbars remove go-k from the guioptions, due to MacVim's
implementation being async compared to normal GVim. May need to
revisit this in the future.
Also fix code indentation for MacVim-specific code to pass the new
Test_indent_of_source_files() test in test_codestyle.vim.
51 lines
1.4 KiB
VimL
51 lines
1.4 KiB
VimL
" Vim filetype plugin file
|
|
" Language: Vim help file
|
|
" Previous Maintainer: Nikolai Weibull <now@bitwi.se>
|
|
" Last Change: 2025 Apr 08
|
|
" 2025 Apr 08 by Vim project (set 'omnifunc' and 'iskeyword', #17073)
|
|
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
let b:did_ftplugin = 1
|
|
|
|
let s:cpo_save = &cpo
|
|
set cpo&vim
|
|
|
|
let b:undo_ftplugin = "setl isk< fo< tw< cole< cocu< keywordprg< omnifunc<"
|
|
|
|
setlocal formatoptions+=tcroql textwidth=78 keywordprg=:help omnifunc=s:HelpComplete
|
|
let &l:iskeyword='!-~,^*,^|,^",192-255'
|
|
if has("conceal")
|
|
setlocal cole=2 cocu=nc
|
|
endif
|
|
|
|
if has("gui_macvim")
|
|
" Use swipe gesture to navigate back/forward
|
|
nmap <buffer> <silent> <SwipeLeft> :po<CR>
|
|
nmap <buffer> <silent> <SwipeRight> :ta<CR>
|
|
endif
|
|
|
|
if !exists('*s:HelpComplete')
|
|
func s:HelpComplete(findstart, base)
|
|
if a:findstart
|
|
let colnr = col('.') - 1 " Get the column number before the cursor
|
|
let line = getline('.')
|
|
for i in range(colnr - 1, 0, -1)
|
|
if line[i] ==# '|'
|
|
return i + 1 " Don't include the `|` in base
|
|
elseif line[i] ==# "'"
|
|
return i " Include the `'` in base
|
|
endif
|
|
endfor
|
|
else
|
|
return taglist('^' .. a:base)
|
|
\ ->map({_, item -> #{word: item->get('name'), kind: item->get('kind')}})
|
|
\ ->extend(getcompletion(a:base, 'help'))
|
|
endif
|
|
endfunc
|
|
endif
|
|
|
|
let &cpo = s:cpo_save
|
|
unlet s:cpo_save
|