mirror of
https://github.com/apple/swift.git
synced 2025-12-14 20:36:38 +01:00
7cceaff5f3
Type annotations for instruction operands are omitted, e.g. ``` %3 = struct $S(%1, %2) ``` Operand types are redundant anyway and were only used for sanity checking in the SIL parser. But: operand types _are_ printed if the definition of the operand value was not printed yet. This happens: * if the block with the definition appears after the block where the operand's instruction is located * if a block or instruction is printed in isolation, e.g. in a debugger The old behavior can be restored with `-Xllvm -sil-print-types`. This option is added to many existing test files which check for operand types in their check-lines.
45 lines
1.9 KiB
Plaintext
45 lines
1.9 KiB
Plaintext
// RUN: %target-sil-opt -sil-print-types -enable-sil-verify-all %s -onone-simplification -simplify-instruction=alloc_ref_dynamic | %FileCheck %s
|
|
|
|
// REQUIRES: swift_in_compiler
|
|
|
|
import Swift
|
|
import Builtin
|
|
|
|
class BaseClass {
|
|
init()
|
|
}
|
|
|
|
class SubClass: BaseClass {
|
|
override init()
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_alloc_ref_dynamic_with_upcast
|
|
// CHECK: bb0(%0 : $Builtin.Word):
|
|
// CHECK: [[AL:%.*]] = alloc_ref [tail_elems $Int * {{.*}} : $Builtin.Word] $SubClass
|
|
// CHECK: [[UP:%.*]] = upcast [[AL]] : $SubClass to $BaseClass
|
|
// CHECK: [[MO:%.*]] = move_value [lexical] [var_decl] [[UP]] : $BaseClass
|
|
// CHECK: return [[MO]] : $BaseClass
|
|
// CHECK: } // end sil function 'test_alloc_ref_dynamic_with_upcast'
|
|
sil [ossa] @test_alloc_ref_dynamic_with_upcast : $@convention(thin) (Builtin.Word) -> @owned BaseClass {
|
|
bb0(%0 : $Builtin.Word):
|
|
%4 = metatype $@thick SubClass.Type
|
|
%5 = upcast %4 : $@thick SubClass.Type to $@thick BaseClass.Type
|
|
%12 = alloc_ref_dynamic [tail_elems $Int * %0 : $Builtin.Word] %5 : $@thick BaseClass.Type, $BaseClass
|
|
%13 = move_value [lexical] [var_decl] %12 : $BaseClass
|
|
return %13 : $BaseClass
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_alloc_ref_dynamic_without_upcast
|
|
// CHECK: bb0(%0 : $Builtin.Word):
|
|
// CHECK: [[AL:%.*]] = alloc_ref [tail_elems $Int * {{.*}} : $Builtin.Word] $BaseClass
|
|
// CHECK: [[MO:%.*]] = move_value [lexical] [var_decl] [[AL]] : $BaseClass
|
|
// CHECK: return [[MO]] : $BaseClass
|
|
// CHECK: } // end sil function 'test_alloc_ref_dynamic_without_upcast'
|
|
sil [ossa] @test_alloc_ref_dynamic_without_upcast : $@convention(thin) (Builtin.Word) -> @owned BaseClass {
|
|
bb0(%0 : $Builtin.Word):
|
|
%4 = metatype $@thick BaseClass.Type
|
|
%12 = alloc_ref_dynamic [tail_elems $Int * %0 : $Builtin.Word] %4 : $@thick BaseClass.Type, $BaseClass
|
|
%13 = move_value [lexical] [var_decl] %12 : $BaseClass
|
|
return %13 : $BaseClass
|
|
}
|