mirror of
https://github.com/apple/swift.git
synced 2025-12-21 12:14:44 +01:00
8b4ce2c2ff
In WebAssembly, `main` function is mangled differently depending on if it takes argc/argv or not. If it doesn't take them, it's mangled to `main` as well as other platforms, so remove unused argc/argv in executable tests to avoid linkage failure.
107 lines
4.8 KiB
Plaintext
107 lines
4.8 KiB
Plaintext
// RUN: %empty-directory(%t)
|
|
// RUN: %target-build-swift-dylib(%t/%target-library-name(PrintShims)) %S/../../Inputs/print-shims.swift -module-name PrintShims -emit-module -emit-module-path %t/PrintShims.swiftmodule
|
|
// RUN: %target-codesign %t/%target-library-name(PrintShims)
|
|
// RUN: %target-build-swift -g -parse-sil %s -emit-ir -I %t -L %t -lPrintShim | %FileCheck %s --check-prefix=CHECK-LL
|
|
// RUN: %target-build-swift -g -parse-sil %s -module-name main -o %t/main -I %t -L %t -lPrintShims %target-rpath(%t)
|
|
// RUN: %target-codesign %t/main
|
|
// RUN: %target-run %t/main %t/%target-library-name(PrintShims) | %FileCheck %s
|
|
|
|
// REQUIRES: executable_test
|
|
// REQUIRES: swift_test_mode_optimize_none
|
|
// REQUIRES: concurrency
|
|
// REQUIRES: concurrency_runtime
|
|
// UNSUPPORTED: back_deployment_runtime
|
|
|
|
import Builtin
|
|
import Swift
|
|
import PrintShims
|
|
import _Concurrency
|
|
|
|
sil public_external @printGeneric : $@convention(thin) <T> (@in_guaranteed T) -> ()
|
|
sil public_external @printInt64 : $@convention(thin) (Int64) -> ()
|
|
|
|
protocol P {
|
|
func printMe() -> Int64
|
|
}
|
|
|
|
extension P {
|
|
func callPrintMe() async -> Int64
|
|
}
|
|
|
|
struct I : P {
|
|
@_hasStorage let int: Int64 { get }
|
|
func printMe() -> Int64
|
|
init(int: Int64)
|
|
}
|
|
|
|
// CHECK-LL: @callPrintMeTu =
|
|
// CHECK-LL: define hidden swift{{(tail)?}}cc void @callPrintMe(
|
|
sil hidden @callPrintMe : $@async @convention(method) <Self where Self : P> (@in_guaranteed Self) -> Int64 {
|
|
bb0(%self : $*Self):
|
|
%P_printMe = witness_method $Self, #P.printMe : <Self where Self : P> (Self) -> () -> Int64 : $@convention(witness_method: P) <τ_0_0 where τ_0_0 : P> (@in_guaranteed τ_0_0) -> Int64
|
|
%result = apply %P_printMe<Self>(%self) : $@convention(witness_method: P) <τ_0_0 where τ_0_0 : P> (@in_guaranteed τ_0_0) -> Int64
|
|
return %result : $Int64
|
|
}
|
|
|
|
sil hidden @I_printMe : $@convention(method) (I) -> Int64 {
|
|
bb0(%self : $I):
|
|
%self_addr = alloc_stack $I
|
|
store %self to %self_addr : $*I
|
|
%printGeneric = function_ref @printGeneric : $@convention(thin) <τ_0_0> (@in_guaranteed τ_0_0) -> ()
|
|
%printGeneric_result = apply %printGeneric<I>(%self_addr) : $@convention(thin) <τ_0_0> (@in_guaranteed τ_0_0) -> ()
|
|
dealloc_stack %self_addr : $*I
|
|
%result = struct_extract %self : $I, #I.int
|
|
return %result : $Int64
|
|
}
|
|
|
|
sil private [transparent] [thunk] @I_P_printMe : $@convention(witness_method: P) (@in_guaranteed I) -> Int64 {
|
|
bb0(%self_addr : $*I):
|
|
%self = load %self_addr : $*I
|
|
%I_printMe = function_ref @I_printMe : $@convention(method) (I) -> Int64
|
|
%result = apply %I_printMe(%self) : $@convention(method) (I) -> Int64
|
|
return %result : $Int64
|
|
}
|
|
|
|
sil @test_case : $@convention(thin) @async () -> () {
|
|
%i_type = metatype $@thin I.Type
|
|
%i_int_literal = integer_literal $Builtin.Int64, 99
|
|
%i_int = struct $Int64 (%i_int_literal : $Builtin.Int64)
|
|
%i = struct $I (%i_int : $Int64)
|
|
%i_addr = alloc_stack $I
|
|
store %i to %i_addr : $*I
|
|
%callPrintMe = function_ref @callPrintMe : $@async @convention(method) <τ_0_0 where τ_0_0 : P> (@in_guaranteed τ_0_0) -> Int64
|
|
%result = apply %callPrintMe<I>(%i_addr) : $@async @convention(method) <τ_0_0 where τ_0_0 : P> (@in_guaranteed τ_0_0) -> Int64 // CHECK: I(int: 99)
|
|
dealloc_stack %i_addr : $*I
|
|
%printInt64 = function_ref @printInt64 : $@convention(thin) (Int64) -> ()
|
|
%printInt64_result = apply %printInt64(%result) : $@convention(thin) (Int64) -> () // CHECK: 99
|
|
|
|
%void = tuple()
|
|
return %void : $()
|
|
}
|
|
|
|
// Defined in _Concurrency
|
|
sil @$ss13_runAsyncMainyyyyYaKcF : $@convention(thin) (@guaranteed @async @callee_guaranteed () -> @error Error) -> ()
|
|
|
|
sil @no_throw_to_throw_think : $@convention(thin) @async (@guaranteed @async @callee_guaranteed () -> ()) -> @error Error {
|
|
bb0(%0 :$@async @callee_guaranteed () -> ()):
|
|
%void = apply %0() : $@async @callee_guaranteed () -> ()
|
|
return %void : $()
|
|
}
|
|
|
|
// main
|
|
sil @main : $@convention(c) () -> Int32 {
|
|
%test_case_nothrow = function_ref @test_case : $@convention(thin) @async () -> ()
|
|
%thick_test_case = thin_to_thick_function %test_case_nothrow : $@convention(thin) @async () -> () to $@callee_guaranteed @async () -> ()
|
|
%thunk = function_ref @no_throw_to_throw_think : $@convention(thin) @async (@guaranteed @async @callee_guaranteed () -> ()) -> @error Error
|
|
%throwing = partial_apply [callee_guaranteed] %thunk(%thick_test_case) : $@convention(thin) @async (@guaranteed @async @callee_guaranteed () -> ()) -> @error Error
|
|
%runAsyncMain = function_ref @$ss13_runAsyncMainyyyyYaKcF : $@convention(thin) (@guaranteed @async @callee_guaranteed () -> @error Error) -> ()
|
|
%result = apply %runAsyncMain(%throwing) : $@convention(thin) (@guaranteed @async @callee_guaranteed () -> @error Error) -> ()
|
|
%out_literal = integer_literal $Builtin.Int32, 0
|
|
%out = struct $Int32 (%out_literal : $Builtin.Int32)
|
|
return %out : $Int32
|
|
}
|
|
|
|
sil_witness_table hidden I: P module main {
|
|
method #P.printMe: <Self where Self : P> (Self) -> () -> Int64 : @I_P_printMe
|
|
}
|