mirror of
https://github.com/apple/swift.git
synced 2025-12-21 12:14:44 +01:00
53bfc767a3
SIL type lowering erases DynamicSelfType, so we generate incorrect code when casting to DynamicSelfType. Fixing this requires a fair amount of plumbing, but most of the changes are mechanical. Note that the textual SIL syntax for casts has changed slightly; the target type is now a formal type without a '$', not a SIL type. Also, the unconditional_checked_cast_value and checked_cast_value_br instructions now take the _source_ formal type as well, just like the *_addr forms they are intended to replace.
84 lines
2.1 KiB
Plaintext
84 lines
2.1 KiB
Plaintext
// RUN: %target-sil-opt -enable-sil-verify-all %s -sil-combine -remove-runtime-asserts | %FileCheck %s
|
|
|
|
sil_stage canonical
|
|
|
|
import Builtin
|
|
import Swift
|
|
|
|
class RawBuffer {}
|
|
class HeapBufferStorage<T, U> : RawBuffer {}
|
|
|
|
class C {
|
|
}
|
|
class D : C {
|
|
}
|
|
class E {
|
|
}
|
|
|
|
// CHECK-LABEL: sil @test_unconditional_checked_cast
|
|
// CHECK: bb0
|
|
// CHECK-NEXT: unchecked_ref_cast
|
|
// CHECK-NEXT: return
|
|
sil @test_unconditional_checked_cast : $@convention(thin) <T_0_0, T_0_1> (RawBuffer) -> HeapBufferStorage<T_0_0, T_0_1> {
|
|
bb0(%0 : $RawBuffer):
|
|
%3 = unconditional_checked_cast %0 : $RawBuffer to HeapBufferStorage<T_0_0, T_0_1>
|
|
return %3 : $HeapBufferStorage<T_0_0, T_0_1>
|
|
}
|
|
|
|
// CHECK-LABEL: sil @test_cond_fail
|
|
// CHECK: bb0
|
|
// CHECK-NEXT: tuple ()
|
|
// CHECK-NEXT: return
|
|
sil @test_cond_fail : $@convention(thin) (Builtin.Int1) -> () {
|
|
bb0(%0 : $Builtin.Int1):
|
|
cond_fail %0 : $Builtin.Int1
|
|
%2 = tuple ()
|
|
return %2 : $()
|
|
}
|
|
|
|
// CHECK-LABEL: sil @test_unconditional_checked_cast_addr_fail
|
|
// CHECK: bb0
|
|
// CHECK-NEXT: store undef
|
|
// CHECK-NEXT: destroy_addr
|
|
// CHECK-NEXT: builtin "int_trap"
|
|
// CHECK: unreachable
|
|
// CHECK: }
|
|
sil @test_unconditional_checked_cast_addr_fail : $@convention(thin) (@in E, @in D) -> @out D {
|
|
bb0(%0 : $*D, %1 : $*E, %2 : $*D):
|
|
unconditional_checked_cast_addr E in %1 : $*E to D in %0 : $*D
|
|
%4 = load %2 : $*D
|
|
strong_release %4 : $D
|
|
%6 = tuple ()
|
|
return %6 : $()
|
|
}
|
|
|
|
// CHECK-LABEL: sil @test_unconditional_checked_cast_other_use
|
|
// CHECK: bb0([[ARG:%.*]] : $C
|
|
// CHECK-NOT: unconditional_checked_cast
|
|
// CHECK: return [[ARG]]
|
|
|
|
sil @test_unconditional_checked_cast_other_use : $@convention(thin) (@owned C) -> @owned C {
|
|
bb0(%0 : $C):
|
|
strong_retain %0 : $C
|
|
%3 = unconditional_checked_cast %0 : $C to C
|
|
strong_release %0 : $C
|
|
return %3 : $C
|
|
}
|
|
|
|
protocol Class : class {
|
|
}
|
|
|
|
class G : Class {
|
|
}
|
|
|
|
// CHECK-LABEL: sil @test_unconditional_checked_cast_class_exist
|
|
// CHECK: unchecked_ref_cast
|
|
// CHECK: return
|
|
sil @test_unconditional_checked_cast_class_exist : $@convention(thin) (@owned Class) -> @owned G {
|
|
bb0(%0 : $Class):
|
|
strong_retain %0 : $Class
|
|
%2 = unconditional_checked_cast %0 : $Class to G
|
|
strong_release %0 : $Class
|
|
return %2 : $G
|
|
}
|