mirror of
https://github.com/apple/swift.git
synced 2025-12-21 12:14:44 +01:00
70ab38d9da
I am going to use this to unwrap ${ @moveOnly T } so that I can pass it to
partial_apply that expect a ${ T }
221 lines
11 KiB
Plaintext
221 lines
11 KiB
Plaintext
// RUN: %target-sil-opt %s | %target-sil-opt | %FileCheck %s
|
|
|
|
import Builtin
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_copy_release_value
|
|
// CHECK: bb0([[T0:%[0-9]+]] : @owned $Builtin.NativeObject):
|
|
// CHECK-NEXT: [[COPY_RESULT:%.*]] = copy_value [[T0]] : $Builtin.NativeObject
|
|
// CHECK-NEXT: destroy_value [[T0]] : $Builtin.NativeObject
|
|
// CHECK-NEXT: return [[COPY_RESULT]]
|
|
sil [ossa] @test_copy_release_value : $@convention(thin) (@owned Builtin.NativeObject) -> @owned Builtin.NativeObject {
|
|
bb0(%0 : @owned $Builtin.NativeObject):
|
|
%1 = copy_value %0 : $Builtin.NativeObject
|
|
destroy_value %0 : $Builtin.NativeObject
|
|
return %1 : $Builtin.NativeObject
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_strong_copy_unowned_value : $@convention(thin) (@owned @sil_unowned Builtin.NativeObject) -> @owned Builtin.NativeObject {
|
|
// CHECK: bb0([[T0:%[0-9]+]] : @owned $@sil_unowned Builtin.NativeObject):
|
|
// CHECK-NEXT: [[COPY_RESULT:%.*]] = strong_copy_unowned_value [[T0]] : $@sil_unowned Builtin.NativeObject
|
|
// CHECK-NEXT: destroy_value [[T0]] : $@sil_unowned Builtin.NativeObject
|
|
// CHECK-NEXT: return [[COPY_RESULT]] : $Builtin.NativeObject
|
|
sil [ossa] @test_strong_copy_unowned_value : $@convention(thin) (@owned @sil_unowned Builtin.NativeObject) -> @owned Builtin.NativeObject {
|
|
bb0(%0 : @owned $@sil_unowned Builtin.NativeObject):
|
|
%1 = strong_copy_unowned_value %0 : $@sil_unowned Builtin.NativeObject
|
|
destroy_value %0 : $@sil_unowned Builtin.NativeObject
|
|
return %1 : $Builtin.NativeObject
|
|
}
|
|
|
|
sil [ossa] @strong_copy_unmanaged_value_test : $@convention(thin) (@sil_unmanaged Builtin.NativeObject) -> @owned Builtin.NativeObject {
|
|
bb0(%0 : $@sil_unmanaged Builtin.NativeObject):
|
|
%1 = strong_copy_unmanaged_value %0 : $@sil_unmanaged Builtin.NativeObject
|
|
return %1 : $Builtin.NativeObject
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_destroy_poison
|
|
// CHECK: bb0([[T0:%[0-9]+]] : @owned $Builtin.NativeObject):
|
|
// CHECK-NEXT: destroy_value [poison] [[T0]] : $Builtin.NativeObject
|
|
// CHECK-NEXT: tuple
|
|
// CHECK-NEXT: return
|
|
sil [ossa] @test_destroy_poison : $@convention(thin) (@owned Builtin.NativeObject) -> () {
|
|
bb0(%0 : @owned $Builtin.NativeObject):
|
|
destroy_value [poison] %0 : $Builtin.NativeObject
|
|
%2 = tuple ()
|
|
return %2 : $()
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_movevalue_parsing : $@convention(thin) (@owned Builtin.NativeObject) -> @owned Builtin.NativeObject {
|
|
// CHECK: bb0([[REGISTER_0:%[^,]+]] :
|
|
// CHECK-NEXT: [[REGISTER_1:%[^,]+]] = move_value [[REGISTER_0]]
|
|
// CHECK-NEXT: [[REGISTER_2:%[^,]+]] = move_value [allows_diagnostics] [[REGISTER_1]]
|
|
// CHECK-NEXT: [[REGISTER_3:%[^,]+]] = move_value [lexical] [[REGISTER_2]]
|
|
// CHECK-NEXT: [[REGISTER_4:%[^,]+]] = move_value [allows_diagnostics] [lexical] [[REGISTER_3]]
|
|
// CHECK-NEXT: [[REGISTER_5:%[^,]+]] = move_value [allows_diagnostics] [lexical] [[REGISTER_4]]
|
|
// CHECK-NEXT: [[REGISTER_6:%[^,]+]] = move_value [allows_diagnostics] [lexical] [pointer_escape] [[REGISTER_5]]
|
|
// CHECK-NEXT: return [[REGISTER_6]]
|
|
// CHECK-NEXT: } // end sil function 'test_movevalue_parsing'
|
|
sil [ossa] @test_movevalue_parsing : $@convention(thin) (@owned Builtin.NativeObject) -> @owned Builtin.NativeObject {
|
|
bb0(%0 : @owned $Builtin.NativeObject):
|
|
%1 = move_value %0 : $Builtin.NativeObject
|
|
%2 = move_value [allows_diagnostics] %1 : $Builtin.NativeObject
|
|
%3 = move_value [lexical] %2 : $Builtin.NativeObject
|
|
%4 = move_value [allows_diagnostics] [lexical] %3 : $Builtin.NativeObject
|
|
%5 = move_value [lexical] [allows_diagnostics] %4 : $Builtin.NativeObject
|
|
%6 = move_value [pointer_escape] [lexical] [allows_diagnostics] %5 : $Builtin.NativeObject
|
|
return %6 : $Builtin.NativeObject
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_debug_value_alloc_stack_moved : $@convention(thin) (@owned Builtin.NativeObject) -> () {
|
|
// CHECK: debug_value [moveable_value_debuginfo] %0 : $Builtin.NativeObject
|
|
// CHECK: debug_value [poison] %0 : $Builtin.NativeObject
|
|
// CHECK: debug_value [poison] [moveable_value_debuginfo] %0 : $Builtin.NativeObject
|
|
// CHECK: debug_value [poison] [moveable_value_debuginfo] %0 : $Builtin.NativeObject
|
|
// CHECK: alloc_stack [moveable_value_debuginfo] $Builtin.NativeObject
|
|
// CHECK: } // end sil function 'test_debug_value_alloc_stack_moved'
|
|
sil [ossa] @test_debug_value_alloc_stack_moved : $@convention(thin) (@owned Builtin.NativeObject) -> () {
|
|
bb0(%0 : @owned $Builtin.NativeObject):
|
|
debug_value [moveable_value_debuginfo] %0 : $Builtin.NativeObject
|
|
debug_value [poison] %0 : $Builtin.NativeObject
|
|
debug_value [moveable_value_debuginfo] [poison] %0 : $Builtin.NativeObject
|
|
debug_value [poison] [moveable_value_debuginfo] %0 : $Builtin.NativeObject
|
|
|
|
%1 = alloc_stack [moveable_value_debuginfo] $Builtin.NativeObject
|
|
dealloc_stack %1 : $*Builtin.NativeObject
|
|
|
|
destroy_value %0 : $Builtin.NativeObject
|
|
%9999 = tuple()
|
|
return %9999 : $()
|
|
}
|
|
|
|
// Make sure that we properly can parse/print/round trip move only type annotation.
|
|
// CHECK-LABEL: sil [ossa] @test_moveonlytype_parsing : $@convention(thin) (@owned @moveOnly Builtin.NativeObject) -> () {
|
|
// CHECK: bb0(%0 : @owned $@moveOnly Builtin.NativeObject):
|
|
// CHECK-NEXT: %1 = copy_value %0 : $@moveOnly Builtin.NativeObject
|
|
// CHECK-NEXT: destroy_value %0 : $@moveOnly Builtin.NativeObject
|
|
// CHECK-NEXT: destroy_value %1 : $@moveOnly Builtin.NativeObject
|
|
// CHECK: } // end sil function 'test_moveonlytype_parsing'
|
|
sil [ossa] @test_moveonlytype_parsing : $@convention(thin) (@owned @moveOnly Builtin.NativeObject) -> () {
|
|
bb0(%0 : @owned $@moveOnly Builtin.NativeObject):
|
|
%1 = copy_value %0 : $@moveOnly Builtin.NativeObject
|
|
destroy_value %0 : $@moveOnly Builtin.NativeObject
|
|
destroy_value %1 : $@moveOnly Builtin.NativeObject
|
|
%9999 = tuple()
|
|
return %9999 : $()
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_explicit_copy_addr : $@convention(thin) (@owned Builtin.NativeObject) -> () {
|
|
// CHECK: explicit_copy_addr %{{[0-9]+}} to [init] %{{[0-9]+}} :
|
|
// CHECK: explicit_copy_addr [take] %{{[0-9]+}} to [init] %{{[0-9]+}} :
|
|
// CHECK: explicit_copy_addr [take] %{{[0-9]+}} to %{{[0-9]+}} :
|
|
// CHECK: explicit_copy_addr %{{[0-9]+}} to %{{[0-9]+}} :
|
|
// CHECK: } // end sil function 'test_explicit_copy_addr'
|
|
sil [ossa] @test_explicit_copy_addr : $@convention(thin) (@owned Builtin.NativeObject) -> () {
|
|
bb0(%0 : @owned $Builtin.NativeObject):
|
|
%1 = alloc_stack $Builtin.NativeObject
|
|
%2 = alloc_stack $Builtin.NativeObject
|
|
%3 = alloc_stack $Builtin.NativeObject
|
|
|
|
%0a = copy_value %0 : $Builtin.NativeObject
|
|
store %0a to [init] %1 : $*Builtin.NativeObject
|
|
explicit_copy_addr %1 to [init] %2 : $*Builtin.NativeObject
|
|
explicit_copy_addr [take] %2 to [init] %3 : $*Builtin.NativeObject
|
|
explicit_copy_addr [take] %3 to %1 : $*Builtin.NativeObject
|
|
|
|
store %0 to [init] %2 : $*Builtin.NativeObject
|
|
explicit_copy_addr %1 to %2 : $*Builtin.NativeObject
|
|
|
|
destroy_addr %2 : $*Builtin.NativeObject
|
|
destroy_addr %1 : $*Builtin.NativeObject
|
|
dealloc_stack %3 : $*Builtin.NativeObject
|
|
dealloc_stack %2 : $*Builtin.NativeObject
|
|
dealloc_stack %1 : $*Builtin.NativeObject
|
|
%9999 = tuple()
|
|
return %9999 : $()
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_allocbox_parsing : $@convention(thin) () -> () {
|
|
// CHECK: alloc_box [pointer_escape] [moveable_value_debuginfo] ${ var Builtin.NativeObject }
|
|
// CHECK: } // end sil function 'test_allocbox_parsing'
|
|
sil [ossa] @test_allocbox_parsing : $@convention(thin) () -> () {
|
|
bb0:
|
|
%0 = alloc_box [moveable_value_debuginfo] [pointer_escape] ${ var Builtin.NativeObject }
|
|
dealloc_box %0 : ${ var Builtin.NativeObject }
|
|
%9999 = tuple()
|
|
return %9999 : $()
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_beginborrow_parsing :
|
|
// CHECK: %1 = begin_borrow [pointer_escape] %0 : $Builtin.NativeObject
|
|
// CHECK-LABE: } // end sil function 'test_beginborrow_parsing'
|
|
sil [ossa] @test_beginborrow_parsing : $@convention(thin) (@owned Builtin.NativeObject) -> () {
|
|
bb0(%0 : @owned $Builtin.NativeObject):
|
|
%1 = begin_borrow [pointer_escape] %0 : $Builtin.NativeObject
|
|
%2 = unchecked_bitwise_cast %1 : $Builtin.NativeObject to $Builtin.Int64
|
|
end_borrow %1 : $Builtin.NativeObject
|
|
destroy_value %0 : $Builtin.NativeObject
|
|
%t = tuple ()
|
|
return %t : $()
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_escapingarg_parsing :
|
|
// CHECK: bb1(%2 : @pointer_escape @owned $Builtin.NativeObject):
|
|
// CHECK-LABEL: } // end sil function 'test_escapingarg_parsing'
|
|
sil [ossa] @test_escapingarg_parsing : $@convention(thin) (@owned Builtin.NativeObject) -> () {
|
|
bb0(%0 : @owned $Builtin.NativeObject):
|
|
br bb1(%0 : $Builtin.NativeObject)
|
|
|
|
bb1(%2 : @pointer_escape @owned $Builtin.NativeObject):
|
|
destroy_value %2 : $Builtin.NativeObject
|
|
%t = tuple ()
|
|
return %t : $()
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_copyable_to_moveonlywrapper : $@convention(thin) (@owned Builtin.NativeObject) -> () {
|
|
// CHECK: copyable_to_moveonlywrapper
|
|
// CHECK: } // end sil function 'test_copyable_to_moveonlywrapper'
|
|
sil [ossa] @test_copyable_to_moveonlywrapper : $@convention(thin) (@owned Builtin.NativeObject) -> () {
|
|
bb0(%0 : @owned $Builtin.NativeObject):
|
|
%0a = copyable_to_moveonlywrapper [owned] %0 : $Builtin.NativeObject
|
|
destroy_value %0a : $@moveOnly Builtin.NativeObject
|
|
%9999 = tuple()
|
|
return %9999 : $()
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_moveonlywrapper_to_copyable_addr : $@convention(thin) (@in Builtin.NativeObject) -> () {
|
|
// CHECK: moveonlywrapper_to_copyable_addr
|
|
// CHECK: } // end sil function 'test_moveonlywrapper_to_copyable_addr'
|
|
sil [ossa] @test_moveonlywrapper_to_copyable_addr : $@convention(thin) (@in Builtin.NativeObject) -> () {
|
|
bb0(%0 : $*Builtin.NativeObject):
|
|
%1 = alloc_stack $@moveOnly Builtin.NativeObject
|
|
%1a = moveonlywrapper_to_copyable_addr %1 : $*@moveOnly Builtin.NativeObject
|
|
copy_addr [take] %0 to [init] %1a : $*Builtin.NativeObject
|
|
destroy_addr %1 : $*@moveOnly Builtin.NativeObject
|
|
dealloc_stack %1 : $*@moveOnly Builtin.NativeObject
|
|
%9999 = tuple()
|
|
return %9999 : $()
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_copyable_to_moveonlywrapper_addr : $@convention(thin) (@in Builtin.NativeObject) -> () {
|
|
// CHECK: copyable_to_moveonlywrapper_addr
|
|
// CHECK: } // end sil function 'test_copyable_to_moveonlywrapper_addr'
|
|
sil [ossa] @test_copyable_to_moveonlywrapper_addr : $@convention(thin) (@in Builtin.NativeObject) -> () {
|
|
bb0(%0 : $*Builtin.NativeObject):
|
|
%0a = copyable_to_moveonlywrapper_addr %0 : $*Builtin.NativeObject
|
|
destroy_addr %0a : $*@moveOnly Builtin.NativeObject
|
|
%9999 = tuple()
|
|
return %9999 : $()
|
|
}
|
|
|
|
// CHECK-LABEL: sil [ossa] @test_moveonlywrapper_to_copyable_box : $@convention(thin) () -> () {
|
|
// CHECK: [[BOX:%.*]] = alloc_box ${ var @moveOnly Builtin.NativeObject }
|
|
// CHECK: [[CAST:%.*]] = moveonlywrapper_to_copyable_box [[BOX]] : ${ var @moveOnly Builtin.NativeObject }
|
|
// CHECK: dealloc_box [[CAST]] : ${ var Builtin.NativeObject }
|
|
// CHECK: } // end sil function 'test_moveonlywrapper_to_copyable_box'
|
|
sil [ossa] @test_moveonlywrapper_to_copyable_box : $@convention(thin) () -> () {
|
|
bb0:
|
|
%0 = alloc_box ${ var @moveOnly Builtin.NativeObject }
|
|
%1 = moveonlywrapper_to_copyable_box %0 : ${ var @moveOnly Builtin.NativeObject }
|
|
dealloc_box %1 : ${ var Builtin.NativeObject }
|
|
%9999 = tuple ()
|
|
return %9999 : $()
|
|
} |