mirror of
https://github.com/apple/swift.git
synced 2025-12-21 12:14:44 +01:00
7cceaff5f3
Type annotations for instruction operands are omitted, e.g. ``` %3 = struct $S(%1, %2) ``` Operand types are redundant anyway and were only used for sanity checking in the SIL parser. But: operand types _are_ printed if the definition of the operand value was not printed yet. This happens: * if the block with the definition appears after the block where the operand's instruction is located * if a block or instruction is printed in isolation, e.g. in a debugger The old behavior can be restored with `-Xllvm -sil-print-types`. This option is added to many existing test files which check for operand types in their check-lines.
116 lines
2.8 KiB
Plaintext
116 lines
2.8 KiB
Plaintext
// RUN: %target-sil-opt -sil-print-types %s -phi-expansion | %FileCheck %s
|
|
|
|
sil_stage canonical
|
|
|
|
import Builtin
|
|
import Swift
|
|
import SwiftShims
|
|
|
|
struct Mystruct {
|
|
@_hasStorage var i: Int { get set }
|
|
@_hasStorage var j: Int { get set }
|
|
init(i: Int)
|
|
}
|
|
|
|
// CHECK-LABEL: sil @test_simple
|
|
// CHECK: br bb3(%{{[0-9]*}} : $Int)
|
|
// CHECK: bb3(%{{[0-9]*}} : $Int):
|
|
// CHECK: } // end sil function 'test_simple'
|
|
sil @test_simple : $@convention(thin) (Mystruct, Mystruct) -> Int {
|
|
bb0(%0 : $Mystruct, %1 : $Mystruct):
|
|
cond_br undef, bb1, bb2
|
|
|
|
bb1:
|
|
br bb3(%0 : $Mystruct)
|
|
|
|
bb2:
|
|
br bb3(%1 : $Mystruct)
|
|
|
|
|
|
bb3(%5 : $Mystruct):
|
|
%6 = struct_extract %5 : $Mystruct, #Mystruct.i
|
|
return %6 : $Int
|
|
}
|
|
|
|
// CHECK-LABEL: sil @test_multiple_struct_extracts
|
|
// CHECK: br bb3(%{{[0-9]*}} : $Int)
|
|
// CHECK: bb3(%{{[0-9]*}} : $Int):
|
|
// CHECK: } // end sil function 'test_multiple_struct_extracts'
|
|
sil @test_multiple_struct_extracts : $@convention(thin) (Mystruct, Mystruct) -> (Int, Int) {
|
|
bb0(%0 : $Mystruct, %1 : $Mystruct):
|
|
cond_br undef, bb1, bb2
|
|
|
|
bb1:
|
|
br bb3(%0 : $Mystruct)
|
|
|
|
bb2:
|
|
br bb3(%1 : $Mystruct)
|
|
|
|
|
|
bb3(%5 : $Mystruct):
|
|
%6 = struct_extract %5 : $Mystruct, #Mystruct.i
|
|
%7 = struct_extract %5 : $Mystruct, #Mystruct.i
|
|
%8 = tuple (%6 : $Int, %7 : $Int)
|
|
return %8 : $(Int, Int)
|
|
}
|
|
|
|
// CHECK-LABEL: sil @dont_transform_multiple_fields
|
|
// CHECK: br bb3(%{{[0-9]*}} : $Mystruct)
|
|
// CHECK: bb3(%{{[0-9]*}} : $Mystruct):
|
|
// CHECK: } // end sil function 'dont_transform_multiple_fields'
|
|
sil @dont_transform_multiple_fields : $@convention(thin) (Mystruct, Mystruct) -> (Int, Int) {
|
|
bb0(%0 : $Mystruct, %1 : $Mystruct):
|
|
cond_br undef, bb1, bb2
|
|
|
|
bb1:
|
|
br bb3(%0 : $Mystruct)
|
|
|
|
bb2:
|
|
br bb3(%1 : $Mystruct)
|
|
|
|
|
|
bb3(%5 : $Mystruct):
|
|
%6 = struct_extract %5 : $Mystruct, #Mystruct.i
|
|
%7 = struct_extract %5 : $Mystruct, #Mystruct.j
|
|
%8 = tuple (%6 : $Int, %7 : $Int)
|
|
return %8 : $(Int, Int)
|
|
}
|
|
|
|
// CHECK-LABEL: sil @test_loop_with_br
|
|
// CHECK: br bb1(%{{[0-9]*}} : $Int)
|
|
// CHECK: bb1(%{{[0-9]*}} : $Int):
|
|
// CHECK: br bb1(%{{[0-9]*}} : $Int)
|
|
// CHECK: } // end sil function 'test_loop_with_br'
|
|
sil @test_loop_with_br : $@convention(thin) (Mystruct) -> Int {
|
|
bb0(%0 : $Mystruct):
|
|
br bb1(%0 : $Mystruct)
|
|
|
|
bb1(%2 : $Mystruct):
|
|
%3 = struct_extract %2 : $Mystruct, #Mystruct.i
|
|
cond_br undef, bb2, bb3
|
|
|
|
bb2:
|
|
br bb1(%2 : $Mystruct)
|
|
|
|
bb3:
|
|
return %3 : $Int
|
|
}
|
|
|
|
// CHECK-LABEL: sil @test_loop_with_cond_br
|
|
// CHECK: br bb1(%{{[0-9]*}} : $Int)
|
|
// CHECK: bb1(%{{[0-9]*}} : $Int):
|
|
// CHECK: cond_br undef, bb1(%{{[0-9]*}} : $Int), bb2
|
|
// CHECK: } // end sil function 'test_loop_with_cond_br'
|
|
sil @test_loop_with_cond_br : $@convention(thin) (Mystruct) -> Int {
|
|
bb0(%0 : $Mystruct):
|
|
br bb1(%0 : $Mystruct)
|
|
|
|
bb1(%2 : $Mystruct):
|
|
%3 = struct_extract %2 : $Mystruct, #Mystruct.i
|
|
cond_br undef, bb1(%2 : $Mystruct), bb2
|
|
|
|
bb2:
|
|
return %3 : $Int
|
|
}
|
|
|